It is currently Thu Sep 18, 2014 11:45 am

All times are UTC - 8 hours




Post new topic Reply to topic  [ 9 posts ] 
Author Message
 Post subject: UBCD2USB and UBCD2ISO
PostPosted: Mon May 12, 2008 1:57 pm 
Offline

Joined: Fri Jan 11, 2008 2:52 pm
Posts: 1278
A lot of people seems to have problems with executing the batch files for making a usb key bootable or to remaster the ISO. It seems necessary to add more text in the batch files, so no so technical users can use those batch files too. I think that you must add so text on how to start the command prompt in windows.

USBCDUSB.bat
http://www.ultimatebootcd.com/forums/viewtopic.php?t=1340

Add something like this (but write it a bit better):
Suppose that you have you unpacked version in "c:\ubcd"

Go to start ==> Run... ==> type "cmd" (without quotes).
Change the directory to "C:\ubcd\tools\ubcd2iso\"
Type the following in the console window.
Code:
ubcd2usb c:\ubcd x:\

(c:\ubcd = path to the extracted UBCD iso, replace x:\ with the right path for your USB key (e.g.: can be d: , e:, f:, g:, h:, ... .See that you choose the right one, because the drive will be formatted)

UBCD2ISO.bat
http://www.ultimatebootcd.com/forums/viewtopic.php?t=1287

Suppose that you have you customized version in "c:\ubcd"

Go to start ==> Run... ==> type "cmd" (without quotes).
Change the directory to "C:\ubcd\tools\ubcd2iso\"
Type the following in the console window.
Quote:
UBCD2ISO c:\ubcd c:\ubcd40.iso

(UBCD extracted in dir 'c:\ubcd', ISO image written to 'c:\ubcd40.iso')
or run it with no parameters to get help (ubcd2iso).

If you want to run the command several times, you can create another batch script. (Open notepad, paste the text from the box below, go to File ==>Save As..., give it a name with .bat at the end, set the Filetype to "All files" and save it). Now you can make you iso just by double clicking on the file.
Quote:
C:\ubcd\tools\ubcd2iso\UBCD2ISO c:\ubcd c:\ubcd40.iso


Top
 Profile  
 
 Post subject: getting error on ubcd2usb towards end of process
PostPosted: Fri May 30, 2008 4:02 am 
Offline

Joined: Thu May 29, 2008 2:13 pm
Posts: 3
I'm having a problem with the script (I thnk)

I mounted the CD to j:\
and my USB drive is k:\


When I get the message " At this point, you might want to unplug and plug in your USB drive", I unmount the drive and then put it back in and press t continue and then get an error "The filename, directory name, or volume label syntax is incorrect."

However it did create the system on the USB it seems. It named my drive "Removable Disk" and it's icon changed, so I don't know if I should worry about this error or not.


Here is the full log:


J:\tools\ubcd2usb>ubcd2usb.bat j:\ k:\

UBCD2USB: Creating bootable UBCD memory stick ...
UBCD2USB: *WARNING* YOUR USB KEY IS ABOUT TO BE REFORMATTED!
Press any key to continue, press ESC to abort
UBCD2USB: *WARNING* YOUR USB KEY CONTENTS WILL BE LOST!
Press any key to continue, press ESC to abort
UBCD2USB: Launching 'makebootfat' to format USB drive
device_start 0 [sectors]
device_size 2004992 [sectors], 979 [MB]
device_geometry 979/64/32 [cylinders/heads/sectors] (ZIP-Drive compatible)
bios_drive HDD
fat_start 32 [sectors]
fat_size 2004960 [sectors]
fat_bit 32
fat_sectorpercluster 8
write 245760 [sectors], 120 [MB]
UBCD2USB: At this point, you might want to unplug and plug in your USB drive
again to refresh the system's view of its content ...
Press any key to continue . . .
The filename, directory name, or volume label syntax is incorrect.
UBCD2USB: Bootable UBCD memory stick has been created

Press any key to continue . . .






Thanks


Top
 Profile  
 
 Post subject:
PostPosted: Fri May 30, 2008 4:52 am 
Offline

Joined: Thu May 29, 2008 2:13 pm
Posts: 3
just add to my previous post, it looks like it didn't property create the USB boot disk as when I try to boot from it it won't boot, I get error:


boot:
menu.c32: attempted DOS system call

and it just keeps cycling that over and over again


Top
 Profile  
 
 Post subject:
PostPosted: Sat Aug 30, 2008 4:21 am 
Offline

Joined: Mon Feb 21, 2005 10:59 pm
Posts: 1288
@nathaliev:

Are you sure you're using the script from the latest UBCD V5 beta?

The script you are using appears to be from UBCD V4.x.


Top
 Profile  
 
 Post subject:
PostPosted: Fri Oct 03, 2008 12:29 am 
Offline

Joined: Fri Mar 11, 2005 11:05 am
Posts: 33
wondering, has anybody though of or made a gui for the make 2usb script or used a tool like unetbootin to set it up? Asking cause; 1) 16gb on sale for $50 @ walmart 2) using unetbootin I've been able to "test" several syslinux distros with (so far) a 1/10 failure rate. It is extremely easy to use and has "addons" for distributions not supported yet.


Top
 Profile  
 
 Post subject:
PostPosted: Fri Oct 03, 2008 1:36 am 
Offline

Joined: Fri Jan 11, 2008 2:52 pm
Posts: 1278
freeballer wrote:
wondering, has anybody though of or made a gui for the make 2usb script

I have send Victor a PM several days ago about it (for inclusion in UBCD creator).

@ Victor:
I think that you should add an option to the ubcd2usb.cmd script which ask if you want to format the drive (isn't needed when the drive is formatted once with a good geometry).

Change ubcd2usb.cmd:
Code:
echo UBCD2USB: *WARNING* YOUR USB KEY IS ABOUT TO BE REFORMATTED!
echo UBCD2USB: *WARNING* YOUR USB KEY CONTENTS WILL BE LOST!
"%~dp0\wait" Press any key to continue, press ESC to abort
if errorlevel 27 if not errorlevel 28 goto _skip

To:
Code:
echo UBCD2USB: *WARNING* YOUR USB KEY IS ABOUT TO BE REFORMATTED!
echo UBCD2USB: *WARNING* YOUR USB KEY CONTENTS WILL BE LOST!
echo Press any key to continue, press 'Ctrl +C' to abort.
pause > nul

The errorlevel line isn't needed anymore.

And delete the following (not needed anymore):
Code:
:_skip
echo UBCD2USB: (bailed out) USB drive untouched
"%~dp0\wait" 5


Now you can delete the wait.com from the /ubcd/tools/ubcd2usb/ directory.

The following line isn't needed (and should be deleted) in ubcd2usb.cmd:
Code:
if not exist "%a1%\syslinux\ldlinux.sys"   %0 : _error Missing file '%a1%\syslinux\ldlinux.sys'

When you execute syslinux.exe, the ldlinux.sys file will be created automatically.

See also the post in the next link about unnecessary files that are still available on UBCD50b5:
http://www.ultimatebootcd.com/forums/viewtopic.php?p=5897#5897


Top
 Profile  
 
 Post subject:
PostPosted: Sat Oct 11, 2008 9:11 pm 
Offline

Joined: Mon Feb 21, 2005 10:59 pm
Posts: 1288
ubcd2usb.cmd updated. The latest ubcd2usb.cmd looks like this:

Code:
@echo off

rem * Create a bootable UBCD memory stick
rem *
rem * UBCD port to USB pioneered by Reblu
rem * http://www.ultimatebootcd.com/forums/viewtopic.php?t=155
rem *
rem * UBCD2USB batch helper authored by Erwin Veermans
rem * Modified by Victor Chew for inclusion in UBCD main distro
rem *
rem * Ultimate Boot CD (UBCD): http://www.ultimatebootcd.com/
rem * syslinux: http://syslinux.zytor.com/

@echo on
@if "%debug%"=="" echo off

SET VOLUME_ID=UBCD50B6

SET a1=%1
SET a1=###%a1%###
SET a1=%a1:"###=%
SET a1=%a1:###"=%
SET a1=%a1:###=%

SET a2=%2
SET a2=###%a2%###
SET a2=%a2:"###=%
SET a2=%a2:###"=%
SET a2=%a2:###=%

if "%a1%"==":" if not "%a2%"=="" goto %a2%
if "%a1%"=="" goto _help
if "%a2%"=="" goto _help

setlocal

:_startops
echo.
echo UBCD2USB: Creating bootable UBCD memory stick ...

:_mkbtft
echo UBCD2USB: *WARNING* YOUR USB KEY IS ABOUT TO BE REFORMATTED!
echo UBCD2USB: *WARNING* YOUR USB KEY CONTENTS WILL BE LOST!
echo Press any key to continue, press 'Ctrl +C' to abort.
pause > nul

:_gomkbt
echo UBCD2USB: Formatting USB KEY...
format "%a2%" /v:%VOLUME_ID% /x /q
if errorlevel 0 goto _gomkbt2
%0 : _error 'format.exe' failed
:_gomkbt2
echo UBCD2USB: Making USB KEY bootable...
"%~dp0\syslinux" -ma -d syslinux %a2%
if errorlevel 0 goto _gomkbt3
%0 : _error 'syslinux.exe' failed
:_gomkbt3
echo UBCD2USB: Copying files to USB KEY...
xcopy "%a1%\*" %a2% /s /h /q
if errorlevel 0 goto _gomkbt4
%0 : _error 'xcopy.exe' failed
:_gomkbt4
if not exist "%a2%\ubcd\tools\ubcd2usb\ubcd2usb.cmd" %0 : _error Missing '%a2%\ubcd\tools\ubcd2usb\ubcd2usb.cmd' (script did not run successfully)
echo UBCD2USB: Bootable UBCD memory stick has been created
goto _end

:_help
echo.
echo UBCD2USB: Create a bootable UBCD memory stick
echo.
echo Usage:    UBCD2USB (UBCD-path) (USB-drive)
echo.
echo Examples: UBCD2USB e: f:
echo           (UBCD-CDROM in 'E:', USB-key in 'F:')
echo.
echo           UBCD2USB "d:\ubcd" f:
echo           (UBCD extracted in dir 'D:\ubcd', USB-key in 'F:')
echo.
echo Requires: W2K/XP/W2K3/Vista and an (optionally extracted) UBCD
cmd.exe /k cd "%~p0"
goto _end

:_error
shift
shift
echo (ERROR) %1 %2 %3 %4 %5 %6 %7 %8
goto _end

:_end


Top
 Profile  
 
 Post subject:
PostPosted: Sun Oct 12, 2008 4:14 pm 
Offline

Joined: Fri Jan 11, 2008 2:52 pm
Posts: 1278
Change:
Code:
echo Press any key to continue, press 'Ctrl +C' to abort.

To:
Code:
echo Press any key to continue, press 'Ctrl + C' to abort.


Top
 Profile  
 
 Post subject:
PostPosted: Fri Dec 05, 2008 12:17 pm 
Offline

Joined: Mon Feb 21, 2005 10:59 pm
Posts: 1288
@IceCube:

I have changed it to:

Code:
echo Press any key to continue, press 'Ctrl+C' to abort.


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 9 posts ] 

All times are UTC - 8 hours


Who is online

Users browsing this forum: No registered users and 2 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  

Protected by Anti-Spam ACP Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group